|
| 1 | +/** Provides predicates for recognizing clickjacking-related response-header configuration. */ |
| 2 | + |
| 3 | +import csharp |
| 4 | +import semmle.code.csharp.dataflow.DataFlow |
| 5 | +import semmle.code.csharp.frameworks.microsoft.AspNetCore |
| 6 | +import semmle.code.csharp.frameworks.system.Web |
| 7 | + |
| 8 | +/** Holds if `name` is the `X-Frame-Options` header name, ignoring case. */ |
| 9 | +bindingset[name] |
| 10 | +predicate isXFrameOptionsHeaderName(string name) { name.toLowerCase() = "x-frame-options" } |
| 11 | + |
| 12 | +/** Holds if `name` is the enforced `Content-Security-Policy` header name, ignoring case. */ |
| 13 | +bindingset[name] |
| 14 | +predicate isContentSecurityPolicyHeaderName(string name) { |
| 15 | + name.toLowerCase() = "content-security-policy" |
| 16 | +} |
| 17 | + |
| 18 | +/** |
| 19 | + * Holds if `value` contains a `frame-ancestors` directive at the start of a CSP policy or |
| 20 | + * after a directive or policy separator. |
| 21 | + */ |
| 22 | +bindingset[value] |
| 23 | +predicate containsFrameAncestorsDirective(string value) { |
| 24 | + value.regexpMatch("(?is)(^|.*[;,])\\s*frame-ancestors(\\s|;|$).*") |
| 25 | +} |
| 26 | + |
| 27 | +private predicate isHeaderNamesField(Expr name, string fieldName) { |
| 28 | + exists(FieldAccess access | |
| 29 | + name.stripImplicit() = access and |
| 30 | + access.getTarget().hasFullyQualifiedName("Microsoft.Net.Http.Headers", "HeaderNames", fieldName) |
| 31 | + ) |
| 32 | +} |
| 33 | + |
| 34 | +private predicate isXFrameOptionsHeaderNameExpr(Expr name) { |
| 35 | + isXFrameOptionsHeaderName(name.stripImplicit().getValue()) |
| 36 | + or |
| 37 | + isHeaderNamesField(name, "XFrameOptions") |
| 38 | +} |
| 39 | + |
| 40 | +private predicate isContentSecurityPolicyHeaderNameExpr(Expr name) { |
| 41 | + isContentSecurityPolicyHeaderName(name.stripImplicit().getValue()) |
| 42 | + or |
| 43 | + isHeaderNamesField(name, "ContentSecurityPolicy") |
| 44 | +} |
| 45 | + |
| 46 | +private predicate containsFrameAncestorsDirectiveExpr(Expr value) { |
| 47 | + containsFrameAncestorsDirective(value.stripImplicit().getValue()) |
| 48 | +} |
| 49 | + |
| 50 | +private predicate isClickjackingHeader(Expr name, Expr value) { |
| 51 | + isXFrameOptionsHeaderNameExpr(name) |
| 52 | + or |
| 53 | + isContentSecurityPolicyHeaderNameExpr(name) and containsFrameAncestorsDirectiveExpr(value) |
| 54 | +} |
| 55 | + |
| 56 | +private predicate isDirectResponseHeadersAccess(Expr expr) { |
| 57 | + exists(PropertyAccessExpr headers, MicrosoftAspNetCoreHttpHttpResponse response | |
| 58 | + expr.stripImplicit() = headers and headers.getProperty() = response.getHeadersProperty() |
| 59 | + ) |
| 60 | +} |
| 61 | + |
| 62 | +private predicate isResponseHeadersAccess(Expr expr) { |
| 63 | + exists(Expr directAccess | |
| 64 | + isDirectResponseHeadersAccess(directAccess) and |
| 65 | + DataFlow::localExprFlow(directAccess, expr.stripImplicit()) |
| 66 | + ) |
| 67 | +} |
| 68 | + |
| 69 | +private Expr getHeaderDictionaryReceiver(MethodCall call) { |
| 70 | + result = call.getQualifier() |
| 71 | + or |
| 72 | + call.getTarget().isExtensionMethod() and |
| 73 | + result = call.getArgumentForParameter(call.getTarget().getParameter(0)) |
| 74 | +} |
| 75 | + |
| 76 | +private predicate isClickjackingHeaderCall(MethodCall call) { |
| 77 | + ( |
| 78 | + call.getTarget() = any(SystemWebHttpResponseClass r).getAppendHeaderMethod() or |
| 79 | + call.getTarget() = any(SystemWebHttpResponseClass r).getAddHeaderMethod() |
| 80 | + ) and |
| 81 | + isClickjackingHeader(call.getArgumentForName("name"), call.getArgumentForName("value")) |
| 82 | + or |
| 83 | + call.getTarget().hasUndecoratedName(["Append", "Add", "TryAdd"]) and |
| 84 | + isResponseHeadersAccess(getHeaderDictionaryReceiver(call)) and |
| 85 | + isClickjackingHeader(call.getArgumentForName("key"), call.getArgumentForName("value")) |
| 86 | +} |
| 87 | + |
| 88 | +private predicate isClickjackingHeaderIndexerAssignment(AssignExpr assignment) { |
| 89 | + exists(IndexerCall indexer | |
| 90 | + assignment.getLeftOperand() = indexer and |
| 91 | + isResponseHeadersAccess(indexer.getQualifier()) and |
| 92 | + isClickjackingHeader(indexer.getArgument(0), assignment.getRightOperand()) |
| 93 | + ) |
| 94 | +} |
| 95 | + |
| 96 | +private predicate isClickjackingNamedHeaderPropertyAssignment(AssignExpr assignment) { |
| 97 | + exists(PropertyAccessExpr header | |
| 98 | + assignment.getLeftOperand() = header and |
| 99 | + isResponseHeadersAccess(header.(QualifiableExpr).getQualifier()) and |
| 100 | + ( |
| 101 | + header.getProperty().hasName("XFrameOptions") |
| 102 | + or |
| 103 | + header.getProperty().hasName("ContentSecurityPolicy") and |
| 104 | + containsFrameAncestorsDirectiveExpr(assignment.getRightOperand()) |
| 105 | + ) |
| 106 | + ) |
| 107 | +} |
| 108 | + |
| 109 | +/** Gets an expression that configures a clickjacking-related response header. */ |
| 110 | +Expr getAClickjackingHeaderWrite() { |
| 111 | + result = any(MethodCall call | isClickjackingHeaderCall(call)) |
| 112 | + or |
| 113 | + result = |
| 114 | + any(AssignExpr assignment | |
| 115 | + isClickjackingHeaderIndexerAssignment(assignment) or |
| 116 | + isClickjackingNamedHeaderPropertyAssignment(assignment) |
| 117 | + ) |
| 118 | +} |
0 commit comments